/*
 * January 2004 - Changed to support H4 device 
 * Copyright (c) 2004 Texas Instruments 
 *
 * (C) Copyright 2002
 * Gary Jennejohn, DENX Software Engineering, <gj@denx.de>
 *
 * See file CREDITS for list of people who contributed to this
 * project.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 */

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)
SECTIONS
{
	. = 0x00000000;

	/* NOBITS section to contain the kernel */
	. = 0x80008000;
	.xkern . (COPY) :
	{
	  __xkern_start = .;
	  . = . + 8M;
	  __xkern_end = .;
	}

	.text      :
	{
	  cpu/omap3/start.o	(.text)
	  *(.text)
	}

	. = ALIGN(4);
	.rodata : { *(.rodata) }

	. = ALIGN(4);
	.data : { *(.data) }

	. = ALIGN(4);
	.bootscript : { *(.bootscript) }

	. = ALIGN(4);
	.got : { *(.got) }

	__u_boot_cmd_start = .;
	.u_boot_cmd : { *(.u_boot_cmd) }
	__u_boot_cmd_end = .;

	. = ALIGN(4);
	__bss_start = .;
	.bss : { *(.bss) }
	. = ALIGN(4);
	_end = .;

	/* NOBITS section to contain the MMU page table */
	. = ALIGN(0x4000);
	.mmu_table . (COPY) :
	{
	  __mmu_table_start = .;
	  . = . + 16K; /* ARM page table is always 16K */
	}

	. = 0x83300000;
	/* NOBITS section to contain the FDT */
	.fdt . (COPY) :
	{
	  __fdt_start = .;
	  . = . + 128K; /* Max FDT len is 128K */
	  __fdt_end = .;
	}

	. = ALIGN(128);
	/* NOBITS section to contain the kernel */
	.kern . (COPY) :
	{
	  . = . + 16K; /* For the decompressor page table */
	  __kern_start = .;
	  . = . + 4M;
	  __kern_end = .;
	}

	. = 0x82000000;
	.diagsys . (COPY) :
	{
	  __diagsys_start = .;
	  . = . + 1M;
	  __diagsys_end = .;
	}

	. = ALIGN(4);

	. = 0x83000000;
	.framebuffer . (COPY) :
	{
	  __framebuffer_start = .;
	  . = . + 3M;
	  __framebuffer_end = .;
	}

	. = ALIGN(4);
}